***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 27, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4444P-AU    drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   505u TC=5m
Rg     g1    g2     1.302
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=275.8  VTO=2.15  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=3.482e11  gamma=1.4)
Rd     d1    d2    3.45m TC=5.3m,15u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=44  TBV1=9.467e-4  TBV2=-1.667e-6 CJO=5.003e-10  M=6.294e-1  VJ=5.070e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.526e-15  N=7.275e-1  RS=12.04u  EG=1.12  TT=20n ikf=6.072e-1)
Rdiode  d1  21    2.317e-3 TC=1.5m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.106e-9
.MODEL     DGD    D(M=5.194e-1   CJO=1.106e-9   VJ=6.092e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.476e-9
.ENDS
*$
